macro set_par
   set *			| all default
   opt *			| all default
   
   set tfon -20			| text & title font
   set gfon -60			| global title font
   set vfon -130		| axis value font
   set lfon -10			| axis label font
   set cfon -60			| comment font
   set txfp -40			| itx font
   set gsiz 0.5			| global title size
   set ygti 1.0			| global title position from top
   set htyp -3			| histogram  fill area type 
   set txal 23			| itx align center & center
   set pwid 5			| box line width
   set smgu 0.06		| stat position from y top axis
   set smgr 0.04		| stat position from x right axis
   
   hi/del *
   hi/file 60 htest.hbook
   hrin 0
   for/clo 60
   
   size 17 24
*   for/file 66 set_par.eps
*   gr/me 66 -113
   
   title 'HBOOK GLOBAL TITLE'
   zon 2 2
   hi/pl 1 b
   hi/pl 2
   opt stat
   zon 1 2 2 s
   max 2 204
   hi/pl 2(10:60) e
   atit 'GeV/C' 'Example of title along Y'
   max 2 -1
   
   for str in_
     xsiz ysiz xmgl xmgr xlab xval xtic_
     ymgl ymgu ylab yval ytic ygti yhti_
     smgr smgu cval gsiz tsiz asiz csiz_
     vsiz xwin ywin hmax baro barw
     [str]=$grafinfo([str])
   endfor
   
   sel 10
   set chhe 0.3
   arrow 0.325 0.375  180 180 -0.1
   itx   0.35  187    'BARW'
   arrow 0.4   0.425  115 115 -0.1
   arrow 0.5   0.4125 135 118  0.1
   itx   0.61  140    'BARO'
   
   sel 20
   wnymax=$grafinfo('wnymax')
   arrow 0.33 0.33 $sigma([wnymax]*[hmax]) [wnymax] -0.2
   itx   0.46 $sigma([wnymax]*(1+[hmax])/2)  'HMAX'
   
   sel 30
   wnxmax=$grafinfo('wnxmax')
   wnxmin=$grafinfo('wnxmin')
   wnymax=$grafinfo('wnymax')
   wnymin=$grafinfo('wnymin')
   arrow 0.15 0.097 145 127  0.1
   itx   0.15 150   'YTIC'
   arrow 0.24 0.297 25  5    0.1
   itx   0.24 30    'XTIC'
   arrow 0.27 0.28  160 160 -0.1
   arrow 0.24 0.274 175 162  0.1
   itx   0.24 180   'ERRX'
   set chhe 0.25
   arrow 0.37 0.37  $sigma([wnymax]*(1-[smgu])) [wnymax] -0.1
   itx   0.34 $sigma([wnymax]*(1-[smgu]/2))   'SMGU'
   set tang 90
   arrow $sigma([wnxmax]-[smgr]*([wnxmax]-[wnxmin])) [wnxmax] 150 150 -0.1
   itx   $sigma([wnxmax]-[smgr]*([wnxmax]-[wnxmin])/2) 135 'SMGR'
   
   sel 1
   
   set chhe 0.3
   set tang 0
   arrow 0 [xmgl] 17.8 17.8 -0.15
   itx   $sigma([xmgl]/2) 18.1 'XMGL'
   arrow $sigma(([xsiz]-[xwin])/2) $sigma(([xsiz]+[xwin])/2)  17.8 17.8 -0.15
   itx   $sigma([xsiz]/2) 18.1 'XWIN'
   arrow [xsiz] $sigma([xsiz]-[xmgr]) 17.8 17.8 -0.15
   itx   $sigma([xsiz]-[xmgr]/2) 18.1 'XMGR'
   arrow [xmgr] $sigma([xmgr]-[xlab]) 11.2 11.2 -0.15
   itx   $sigma([xmgr]-[xlab]/2) 11.5 'XLAB'
   arrow [xmgr] $sigma([xmgr]-[xval]) 6.2 6.2 -0.1
   arrow 3.0  $sigma([xmgr]-0.5*[xval]) 5.2 6.1 0.1
   itx   3.0 5.0  'XVAL'
   arrow 1.9  1.9  [ymgl] $sigma([ymgl]-[yval])  -0.1
   arrow 1.0  1.85 1.5 $sigma([ymgl]-0.5*[yval]) 0.1
   itx   1.0  1.3  'YVAL'
   arrow 10.3 10.3 8.4 $sigma(8.4+[csiz])  -0.1
   arrow 12.0 10.5 7.6 $sigma(8.4+[csiz]/2)  0.1
   itx   12.5 7.4  'CSIZ'
   arrow 0.0  [xsiz] 4.7 4.7  -0.15
   itx   $sigma([xsiz]/2) 5.0 'XSIZ'
   
   set chhe 0.25
   set tang 90
   arrow 12.5 12.5 [ysiz] $sigma([ysiz]-[ygti]) -0.15
   itx   12.8 $sigma([ysiz]-[ygti]/2) 'YGTI'
   arrow 4.2  4.2  $sigma([ysiz]-[ygti]) $sigma([ysiz]-[ygti]-[gsiz]) -0.1
   itx   3.8 $sigma([ysiz]-[ygti]-[gsiz]/2) 'GSIZ'
   arrow 2.5  2.5  [ysiz] $sigma([ysiz]-[ymgu]) -0.15
   itx   2.2 $sigma([ysiz]-[ymgu]/2) 'YMGU'
   arrow 10.0 10.0 $sigma(([ysiz]-[ywin])/2) $sigma(([ysiz]+[ywin])/2) -0.15
   itx   9.8  $sigma([ysiz]/2) 'YWIN'
   arrow 3.5  3.5 0 [ymgl] -0.15
   itx   3.2  $sigma([ymgl]/2) 'YMGL'
   arrow 10.8 10.8 [ymgl] $sigma([ymgl]-[yhti])  -0.15
   itx   11.2 $sigma([ymgl]-[yhti]/2)  'YHTI'
   arrow 16.5 16.5 0.0 [ysiz] -0.15
   itx   16.2 $sigma([ysiz]/2) 'YSIZ'
   
   set chhe 0.2
   arrow 15.4 15.4 [ymgl] $sigma([ymgl]-[ylab])  -0.1
   itx   15.6 $sigma([ymgl]-[ylab]/2) 'XLAB'
   arrow 6.2  6.2  $sigma([ymgl]-[yhti]) $sigma([ymgl]-[yhti]-[tsiz])  -0.1   
   itx   5.9 $sigma([ymgl]-[yhti]-[tsiz]/2)  'TSIZ'
   arrow 1.0  1.0  2.95 $sigma(2.95+[vsiz]) -0.1
   itx   0.8  $sigma(2.95+[vsiz]/2)  'VSIZ'
   arrow 13.7 13.7 $sigma([ymgl]-[ylab]) $sigma([ymgl]-[ylab]-[asiz]) -0.1
   itx   13.4 $sigma([ymgl]-[ylab]-[asiz]/2)  'ASIZ'
   
*   close 66
 return